Licence de Psychologie - TD No 3

Calculs statistiques à l'aide d'un tableur : l'exemple d'Excel

 

 

Corrigés des exercices proposés dans le texte :
manage-correction.xls
Optiques-correction.xls
mireault-correction.xls

 

Vous avez utilisé l'an dernier deux logiciels tableurs : le module tableur d'AppleWorks et Microsoft Excel. Leurs fonctionnalités de base sont semblables. Une caractéristique différencie cependant Excel d'AppleWorks : dans Excel, le document de base n'est pas la traditionnelle "feuille de calcul", mais un "classeur", empilement de plusieurs feuilles mémorisées dans un unique fichier du disque.

Notez que les traitements effectués ci-dessous pourraient également être effectués à l'aide d'OpenOffice Calc, à l'exception de ceux qui utilisent l'utilitaire d'analyse.

1 - Gérer les feuilles d'un classeur : renommer, supprimer, insérer

Ouvrez le document W:\PSY3\TD-EXCEL\manage.xls et réenregistrez-le sur un disque accessible en lecture/écriture (le disque U: ou votre disquette).

Le document comporte trois feuilles. Dans la première, on a inséré un objet "Document WordPad" avec quelques indications concernant la situation proposée. Dans la deuxième, ont été rassemblées les données observées.

On passe d'une feuille à l'autre en cliquant sur l'onglet voulu :

Renommez (à l'aide d'un double clic sur leur onglet) les deux premières feuilles du classeur. La première pourra être appelée Enoncé, et la deuxième Données.

Supprimez la dernière feuille du classeur (clic sur l'onglet pour sélectionner une feuille, puis menu Edition-Supprimer une feuille).

Revenez à la feuille Données et insérez une colonne devant la colonne A. Celle-ci nous servira ultérieurement, pour indiquer des légendes.

2 - Calculs simples. Recopier vers la droite et vers le bas

Les données constituent deux échantillons appariés (chaque ligne correspond à un trimestre donné). Il est donc naturel de s'intéresser à la différence des valeurs portées dans les colonnes C et D.

Saisissez en cellule E1 le texte Différence, puis en cellule E2 la formule : =C2-D2

Recopiez ensuite cette formule jusqu'en E16 (menu Edition - Recopier... En bas, ou faites glisser le coin inférieur droit de la cellule E2).

Indiquez les légendes suivantes :

- En A18 : Somme Observations

- En A19 : Nb Observations

- En A20 : Moyenne

- En A21 : Variance

- En A22 : Ecart type

- En A23 : Variance corrigée

- En A24 : Ecart type corrigé

- En A26 : Mode

- En A27 : Médiane

- En A28 : Ecart moyen

Saisissez ensuite les formules suivantes :

- En C18 : =SOMME(C2:C16)

- En C19 : =NB(C2:C16)

- En C20 : =MOYENNE(C2:C16)

- En C21 : =VAR.P(C2:C16)

- En C22 : =ECARTYPEP(C2:C16)

- En C23 : =VAR(C2:C16)

- En C24 : =ECARTYPE(C2:C16)

- En C26 : =MODE(C2:C16)

- En C27 : =MEDIANE(C2:C16)

- En C28 : =ECART.MOYEN(C2:C16)

Remarque 1. Pour rentrer ces formules, vous pourrez utiliser l'assistant, à condition d'apprendre à réduire ou déplacer sa fenêtre, puis qu'il a la bonne habitude de masquer les choses utiles...

Remarque 2. Alors qu'AppleWorks utilise une notation du type C2..C16 pour désigner une plage de cellules, Excel utilise la notation C2:C16.

Remarque 3. Les fonctions VAR() et ECARTYPE() calculent la variance et l'écart type corrigés (variance obtenue en divisant la somme des carrés des écarts à la moyenne par N-1) alors que VAR.P() et ECARTYPEP() calculent la variance et l'écart type "habituels".

Recopiez la plage C18:C24 vers la droite jusqu'en colonne E.

3 - Mise en forme de la feuille- Formats de nombres

Utilisez le menu Format-Cellule - onglet Nombre pour afficher les valeurs des variances et écarts types avec deux décimales.

Améliorez ensuite la présentation de l'ensemble en modifiant les styles de polices de caractères, en définissant des bordures, etc.

4 - L'utilitaire d'analyse

Du point de vue des traitements statistiques, les fonctions de base d'Excel n'en font guère qu'une calculatrice améliorée avec des tables numériques intégrées. Cependant, le logiciel possède un langage de programmation très complet, et il est possible d'ajouter au programme de base des modules additionnels spécialisés dans des traitements particuliers. Microsoft fournit en standard le module "Utilitaire d'analyse", dont nous allons maintenant donner un premier aperçu.

Selon la façon dont Excel a été installé sur le poste sur lequel vous travaillez, plusieurs cas sont possibles :

- Vous trouvez dans le menu Outils, l'item Utilitaire d'analyse (c'est en principe le cas sur les postes de la Faculté fonctionnant sous Windows XP, lorsque vous ouvrez une session comme "etudiant"). Dans ce cas, vous n'avez rien à faire...

- Si vous ouvrez une session avec votre login personnel (ou si avez l'occasion de travailler sur un poste personnel...), cet item de menu est absent. Dans ce cas, utilisez le menu Outils-Macros complémentaires... et cochez la boîte située devant l'item Utilitaire d'analyse. Si tout se passe bien, Excel charge alors l'utilitaire, et ajoute l'item Utilitaire d'analyse au menu Outils.

4.1. Statistiques descriptives avec l'utilitaire d'analyse

 

Grâce à l'utilitaire d'analyse, nous allons retrouver la plupart des résultats précédents, sans avoir à écrire de formules.

Sélectionnez ensuite le menu Outils-Utilitaire d'analyse, puis, dans la liste affichée, l'item Statistiques Descriptives.

Pour calculer les paramètres des variables H_Incident et D_Incident, on pourra compléter la fenêtre de dialogue de la façon suivante :

Excel compose alors une feuille supplémentaire ayant l'allure ci-dessous, dans laquelle nous pouvons prélever les résultats qui nous intéressent.

H_Incident

D_Incident

Différence
Moyenne

13,13333333

Moyenne

11,2666667

Moyenne

1,86666667

Erreur-type

0,798013406

Erreur-type

0,65803942

Erreur-type

0,60052887

Médiane

12

Médiane

12

Médiane

3

Mode

12

Mode

13

Mode

3

Écart-type

3,090692633

Écart-type

2,5485757

Écart-type

2,3258383

Variance de l'échantillon

9,552380952

Variance de l'échantillon

6,4952381

Variance de l'échantillon

5,40952381

Kurstosis (Coefficient d'applatissement)

1,706985417

Kurstosis (Coefficient d'applatissement)

0,07633696

Kurstosis (Coefficient d'applatissement)

-0,96094716

Coefficient d'assymétrie

1,196117834

Coefficient d'assymétrie

0,58236816

Coefficient d'assymétrie

-0,63980473

Plage

12

Plage

9

Plage

7

Minimum

9

Minimum

8

Minimum

-2

Maximum

21

Maximum

17

Maximum

5

Somme

197

Somme

169

Somme

28

Nombre d'échantillons

15

Nombre d'échantillons

15

Nombre d'échantillons

15

 

5 - Adressage relatif et absolu. Nommer des cellules

L'utilitaire d'analyse ne résout malheureusement pas tous les problèmes. En particulier, il ne fournit aucun item permettant de calculer une distance du khi-2 ou de faire un test du même nom.

5.1 Références absolues et références relatives

Ouvrez le document W:\PSY3\TD-EXCEL\Optiques-sans-hic.xls et réenregistrez-le sur un disque accessible en lecture/écriture (le disque U: ou votre disquette).

Dans la feuille Enoncé, on a inséré un objet "Document WordPad" avec quelques indications concernant la situation proposée. Lisez-le attentivement.

Dans la deuxième, un tableau de contingence résume les données observées.

- Complétez ce tableau en calculant les sommes marginales (sommes par ligne et par colonne) dans les plages B7:F7 et F4:F6.

Dans la plage A11:F15, on veut construire un tableau des fréquences, calculées par rapport à l'effectif total.

- Saisissez en B11 la formule =B3 et recopiez vers la droite jusqu'en F11

- Saisissez en A12 la formule =A4 et recopiez vers le bas jusqu'en A15.

Pour calculer la fréquence du premier couple de modalités, on peut saisir en B12 la formule =B4/F7. Cependant, cette formule ne peut pas être recopiée vers la droite ou vers le bas. Pourquoi ?

Pour résoudre ce problème, deux méthodes peuvent être utilisées. Chacune d'elles va être expérimentée sur une partie du tableau.

Première méthode : utiliser une référence absolue pour l'effectif total.

- Saisissez en B12 la formule =B4/$F$7. Recopiez à droite et vers le bas jusqu'en C15.

Deuxième méthode : définir un nom

- Sélectionnez la cellule F7 puis utilisez le menu Insertion-Nom-Définir... pour attribuer à cette cellule le nom Total.

- Saisissez en D12 la formule : =D4/Total. Vous pouvez utiliser le menu Insertion-Nom-Coller... pendant l'édition de la formule.

- Recopiez à droite et vers le bas jusqu'en F15.

Comme on peut le voir sur cet exemple, un nom, lorsqu'il est appliqué à une cellule unique, équivaut à une référence absolue.

A l'aide de Format-Cellule onglet Nombre catégorie Pourcentage, affichez les fréquences sous forme de pourcentages à deux décimales.

5.2 Références mixtes : calcul du tableau des effectifs théoriques

Nous voulons constituer dans la plage H3:L6 le tableau des effectifs théoriques (sous hypothèse d'indépendance entre les deux variables étudiées). Autrement dit, nous voulons que chacune des cellules de la plage I4:L6 contienne la "formule" : (total ligne)*(total colonne)/(total général).

Ni les références relatives, ni les références absolues ne vont ici convenir. Pourquoi ? Excel autorise cependant également les références mixtes, relatives sur la ligne et absolues sur la colonne, ou l'inverse.

- Saisissez des formules donnant les légendes en ligne 3 et colonne H

- Saisissez en I4 la formule : =B$7*$F4/total. Complétez ensuite en recopiant à droite et vers le bas.

5.3 Calcul des contributions au khi-2. Première méthode

Le calcul des contributions au khi-2 sera fait dans les cellules H11:L14.

- Saisissez des formules donnant les légendes en ligne 3 et en colonne H.

- Saisissez en I12 la formule : =(B4-I4)^2/I4. Complétez ensuite en recopiant à droite et vers le bas.

Calcul du khi-2

- Saisissez en H16 le texte : khi-2=

- Saisissez en I16 la formule : =SOMME(I12:L14)

Remarque 1 : On peut aussi nommer Contrib la plage I12:L14 et saisir la formule =SOMME(Contrib).

Remarque 2 : En calcul manuel, nous calculons en général le khi-2 à l'aide d'un tableau dans lequel les contributions sont rassemblées dans une seule colonne. Mais un tableur fait aussi bien une somme sur un tableau rectangulaire, et les contributions sont ainsi plus faciles à calculer.

5.4 Calcul des contributions au khi-2. Deuxième méthode : calcul sur des "matrices"

 

Nous allons utiliser la plage H20:L23 pour calculer les contributions au khi-2 en utilisant les possibilités de calcul "matriciel" d'Excel.

- Attribuez le nom obs à la plage B4:E6 et le nom theos à la plage I4:L6.

- Sélectionnez la plage I21:L23 et saisissez la formule :

=(obs-theos)^2/theos

- Validez ensuite la formule en appuyant sur Maj+Ctrl+Entrée

Remarque. Nous verrons dans une prochaine séance qu'il est en fait inutile de calculer les contributions au khi-2 pour faire faire à Excel un test du khi-2. En revanche, il est indispensable de calculer les effectifs théoriques.

6. Manipuler un tableau de grande taille. Tris à plat

Ouvrez le document W:\PSY3\TD-EXCEL\mireault.xls.

La deuxième feuille du classeur contient un tableau de grande taille (20 variables observés et 381 sujets, mais certaines valeurs sont manquantes).

Dans une première phase de l'étude de ces données, on veut effectuer un recensement ou tri à plat pour chaque variable. En TD, nous traiterons le cas des variables YearColl, SomT et GSIT. Les autres variables pourront être traitées en monitorat.

6.1 Diviser la fenêtre pour afficher simultanément les premières et les dernières lignes du tableau.

Affichez la feuille Données MIREAULT.

Sélectionnez la colonne D (clic sur la tête de colonne), copiez-la puis collez-la comme colonne A d'une nouvelle feuille. Cette nouvelle feuille sera nommée : YearColl.

Affichez la feuille YearColl. Déplacez le rectangle situé au dessus de l'ascenseur vertical pour diviser la fenêtre en deux sous-fenêtres.

   

Explorez l'ensemble des modalités de la variable YearColl, en calculant en D2, D3 et D4 respectivement le nombre d'observations, la modalité minimum et la modalité maximum. Utilisez pour cela les fonctions MAX, MIN,et NB.

Remarquez l'intérêt présenté par la division de notre fenêtre. La formule =NB(A2:A382), par exemple, pourra être saisie de la manière suivante :

- taper : =NB(

- cliquer sur la cellule A2

- taper : :

- cliquer sur la cellule A382

- taper ) , puis entrée.

6.2 Fonctions renvoyant une matrice. L'exemple de la fonction FREQUENCE.

On veut faire un tri à plat selon les valeurs de la variable YearColl, c'est-à-dire constituer un tableau d'effectifs relatif à cette variable. L'outil fourni par Excel pour réaliser ce travail est la fonction FREQUENCE. Celle-ci présente la particularité d'être une fonction matricielle : elle renvoie, non pas une, mais plusieurs valeurs numériques et il faut donc saisir la formule dans une matrice de taille convenablement choisie.

Saisissez les différentes modalités dans les cellules C7 à C10 :

C

D

7

1

8

2

9

3

10

4

 

Sélectionnez ensuite la plage de cellules D7:D10 et saisissez la formule :

=FREQUENCE(A2:A382;C7:C10)

Validez par Ctrl+Maj+Entrée.

Remarque.

1) Selon les bonnes habitudes américaines, la fonction FREQUENCE renvoie des effectifs et non des fréquences...

2) La fonction FREQUENCE permet d'autres calculs d'effectifs :

- Si toutes les modalités ne sont pas présentes dans le tableau passé en deuxième paramètre, les résultats fournis sont les effectifs de classes ]ai-1, ai] déclarées implicitement par le tableau.

- Si on spécifie un nombre au lieu d'un tableau en deuxième paramètre, FREQUENCE calcule alors l'effectif cumulé correspondant à ce paramètre. Il est inutile dans ce cas de définir une matrice en validant la formule.

Exemple :

Recopiez dans une nouvelle feuille la série d'observations de la variable SomT. Calculez, comme précédemment, le nombre d'observations, le minimum et le maximum des modalités observées. Réalisez un tableau d'effectifs et d'effectifs cumulés relatifs au découpage en classes :

0 ; 41 ; 50 ; 55 ; 60 ; 65 ; 70 ; 75 ; 80

en saisissant les données et formules suivantes :

C

D

E
6 Effectifs Cumuls
7 41 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C7)
8 50 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C8)
9 55 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C9)
10 60 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C10)
11 65 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C11)
12 70 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C12)
13 75 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C13)
14 80 ={FREQUENCE(A2:A382;C7:C14)} =FREQUENCE($A$2:$A$382;C14)
15 =SOMME(D7:D14)

 

6.3 Tris à plat avec l'utilitaire d'analyse

Une partie des résultats précédents peuvent aussi être obtenus à l'aide de l'item Histogramme de l'utilitaire d'analyse.

Par exemple, nous voudrions procéder à un regroupement en classes pour la variable GSIT (colonne R de la feuille Données MIREAULT).

Copiez cette colonne et collez-la comme colonne A d'une nouvelle feuille nommée GSIT.

Vous pourrez vérifier que cette colonne contient des données relatives à 375 sujets (sur 381 sujets étudiés), et que les modalités sont comprises entre 34 et 80.

Cette donnée est manquante pour 6 des 381 sujets. Dans ce cas, la cellule correspondante contient un caractère alphanumérique : le point. Or, l'utilitaire d'analyse refusera de fonctionner si la plage de données contient des valeurs non numériques.

A l'aide du menu Edition - Remplacer, supprimez toutes les occurrences du caractère . (point) de la feuille GSIT.

On choisit le découpage en classes donné par les bornes supérieures suivantes :

30 ; 40 ; 50 ; 60 ; 70 ; 80

Saisissez ces bornes de classes dans la plage C2:C7.

C

1

Jusqu'à

2

30

3

40

4

50

5

60

6

70

7

80

Choisissez ensuite l'item Histogramme de l'utilitaire d'analyse en complétant le dialogue de la manière suivante :

Vous devriez obtenir le résultat suivant :

Jusqu'à

Fréquence

% cumulé

30

0

.00%

40

5

1.33%

50

30

9.33%

60

131

44.27%

70

131

79.20%

80

78

100.00%

ou plus...

0

100.00%

 

7. Exercices de monitorat

Exercice 1

Ouvrez le document W:\PSY3\TD-EXCEL\internat.xls.

Comme dans le cas du document MANAGE.XLS, calculez les paramètres (moyenne, variance díéchantillon et variance corrigée, etc) des deux séries proposées, ainsi que les paramètres de la différence.

Exercice 2

Reprendre líexercice 6 de la fiche de TD de statistiques.

Líénoncé est le suivant :

Soit deux questions díun test, A et B, auxquelles un groupe de 184 sujets a répondu. On voudrait savoir si la fréquence des réussites et des échecs est la même pour A et B. Le tableau des effectifs observés est le suivant :

  B : réussite B : Echec
A : réussite

62

23
A : Echec

58

41

Construire le tableau díeffectifs théoriques permettant díutiliser le khi-2 de Mac Nemar et calculer la distance du khi-2 entre les deux tableaux.

Exercice 3 : Reprendre le document W:\PSY3\TD-EXCEL\mireault.xls.

1) Etablissement d'un tableau de contingence

Il ne semble pas exister de fonction donnant directement un tableau de contingence à partir d'un tableau protocole. Cependant, le menu Données - Trier ... et la fonction FREQUENCE permettent de s'en sortir sans trop de peine.

On veut, par exemple, croiser les variables Gender (sexe) et College (type d'études).

- Copiez les colonnes Gender et College de la feuille Données MIREAULT et collez-les dans les colonnes A et B d'une nouvelle feuille.

- Dans la nouvelle feuille, triez la plage A2:B382 selon les valeurs de la colonne A.

- Constituez le tableau de contingence.

Pour chacun des deux sous-groupes définis par les deux valeurs de la variable Gender, utilisez la fonction FREQUENCE pour calculer les effectifs. On obtiendra par exemple le tableau suivant :

D

E

F

7
Coll\Gender

1

2

8
1 {=FREQUENCE(B2:B144;D8:D12)} {=FREQUENCE(B145:B382;D8:D12)}

9
2 {=FREQUENCE(B2:B144;D8:D12)} {=FREQUENCE(B145:B382;D8:D12)}

10
3 {=FREQUENCE(B2:B144;D8:D12)} {=FREQUENCE(B145:B382;D8:D12)}

11
4 {=FREQUENCE(B2:B144;D8:D12)} {=FREQUENCE(B145:B382;D8:D12)}

12
5 {=FREQUENCE(B2:B144;D8:D12)} {=FREQUENCE(B145:B382;D8:D12)}

 

2) Calculez le tableau d'effectifs théoriques et le khi-2 observé. Conclure à l'aide d'un test au seuil de 5%.

3) Effectuez des tris à plat pour les autres variables du document.

4) Constituez de même un tableau de contingence pour les variables Group et GPA.

5) Les sujets sont répartis en trois groupes selon les valeurs de la variable Group. Calculez les moyennes observées pour les variables des colonnes I à U pour chacun des trois groupes.

Exercice 4

Reprendre les traitements effectués en TD qui n'utilisent pas l'utilitaire d'analyse et les refaire en utilisant OpenOffice Calc.

N.B. Les fichiers Excel peuvent sans problème être ouverts par OpenOffice Calc.

 

8. Les fonctions statistiques d'Excel

Ci-dessous, une liste de fonctions statistiques disponibles sous Excel (source : aide en ligne).

ECART.MOYEN Calcule la moyenne des écarts absolus de points de données à partir de leur moyenne

MOYENNE Calcule la moyenne de ses arguments

AVERAGEA Calcule la moyenne de ses arguments, y compris les nombres, le texte et les valeurs logiques

LOI.BINOMIALE Renvoie la probabilité de distribution binomiale individuelle d'un terme

LOI.KHIDEUX Renvoie la probabilité d'une variable aléatoire continue suivant une loi unilatérale du Khi-deux

KHIDEUX.INVERSE Renvoie, pour une probabilité unilatérale donnée, la valeur d'une variable aléatoire suivant une loi du Khi-deux

TEST.KHIDEUX Renvoie le test d'indépendance

INTERVALLE.CONFIANCE Renvoie l'intervalle de fiabilité pour la moyenne d'une population

COEFFICIENT.CORRELATION Renvoie le coefficient de corrélation entre deux ensembles de données

NB Compte les nombres contenus dans la liste d'arguments

NBVAL Compte les valeurs contenues dans la liste d'arguments

COVARIANCE Renvoie la covariance, la moyenne des produits des écarts appariés

CRITERE.LOI.BINOMIALE Renvoie la plus petite valeur pour laquelle la distribution binomiale cumulative est inférieure ou égale à une valeur de référence

SOMME.CARRES.ECARTS Calcule la somme des carrés des écarts

PREVISION Renvoie une valeur sur une tendance linéaire

FREQUENCE Renvoie une distribution de fréquence sous forme d'un tableau vertical

GRANDE.VALEUR Renvoie la kième plus grande valeur d'une série de données

MAX Renvoie la valeur maximale d'une liste d'arguments

MAXA Renvoie la valeur maximale d'une liste d'arguments, y compris les nombres, le texte et les valeurs logiques

MEDIANE Renvoie la médiane des nombres spécifiés

MIN Renvoie la valeur minimale d'une liste d'arguments

MINA Renvoie la plus petite valeur d'une liste d'arguments, y compris les nombres, le texte et les valeurs logiques

MODE Renvoie la valeur la plus courante d'une série de données

LOI.NORMALE Renvoie la probabilité d'une variable aléatoire continue suivant une loi normale

LOI.NORMALE.INVERSE Renvoie, pour une probabilité donnée, la valeur d'une variable aléatoire suivant une loi normale

LOI.NORMALE.STANDARD Renvoie la distribution cumulée suivant une loi normale standard

LOI.NORMALE.STANDARD.INVERSE Renvoie, pour une probabilité donnée, la valeur d'une variable aléatoire suivant une loi normale standard

CENTILE Renvoie le kième centile des valeurs d'une plage

RANG.POURCENTAGE Renvoie le rang en pourcentage d'une valeur dans une série de données

PERMUTATION Renvoie le nombre de permutations d'un nombre donné d'objets

QUARTILE Renvoie le quartile d'une série de données

RANG Renvoie le rang d'un nombre dans une liste d'arguments

COEFFICIENT.DETERMINATION Renvoie le carré du coefficient de corrélation d'échantillonnage de Pearson

PENTE Renvoie la pente de la ligne de régression linéaire

PETITE.VALEUR Renvoie la kième plus petite valeur d'une série de données

CENTREE.REDUITE Renvoie une valeur normalisée

ECARTYPE Évalue l'écart type à partir d'un échantillon

STDEVA Évalue l'écart type à partir d'un échantillon, y compris les nombres, le texte et les valeurs logiques

ECARTYPEP Calcule l'écart type à partir de la population entière

STDEVPA Calcule l'écart type à partir de la population entière, y compris les nombres, le texte et les valeurs logiques

LOI.STUDENT Renvoie la probabilité d'une variable aléatoire suivant une loi T de Student

LOI.STUDENT.INVERSE Renvoie, pour une probabilité donnée, la valeur d'une variable aléatoire suivant une loi T de Student

MOYENNE.REDUITE Renvoie la moyenne de l'intérieur d'une série de données

TEST.STUDENT Renvoie la probabilité associée à un test T de Student

VAR Évalue la variance à partir d'un échantillon

VARA Évalue la variance à partir d'un échantillon, y compris les nombres, le texte et les valeurs logiques

VAR.P Calcule la variance à partir de la population entière

VARPA Calcule la variance à partir de la population entière, y compris les nombres, le texte et les valeurs logiques

TEST.Z Renvoie la valeur bilatérale P du test Z